;5. program
        org 01000h      ; 1
                        ; 2 EXOS valtozo allitasa makro
evar macro @exvar,@val
        ld b,1          ; 4
        ld c,@exvar     ; 5
        ld d,@val       ; 6
        exos 16         ; 7
        endm            ; 8
                        ; 9 kepernyomeretek
x_size  equ 40          ;10 video x
y_size  equ 27          ;11 video y
                        ;12
                        ;13 a kepernyo definialasa
        evar 22,0       ;14 video mode
        evar 23,0       ;15 video color
        evar 24,x_size  ;16 video x
        evar 25,y_size  ;17 video y
                        ;18
                        ;19 a kepernyo csatorna megnyitasa
        ld a,10         ;20 a csatorna szama
        ld de,vid       ;21 mutato a nevre
        exos 1          ;22 csatorna megnyitas
                        ;23
                        ;24 szekvenciak elkuldese
        ld a,10         ;25 ide kuldunk
        ld bc,seqlen    ;26 ennyi bajtot
        ld de,seq       ;27 itt kezdodo
        exos 9          ;28 szekvenciat
                        ;29
                        ;30 megjelenites (DISP)
        ld a,10         ;31
        ld b,1          ;32
        ld e,1          ;33
        ld c,1          ;34
        ld d,y_size     ;35
        exos 11         ;36
                        ;37
                        ;38 a karakterek megjelenitese
        ld a,33         ;39 ASCII 33=!
cycl_0  push af         ;40 karakterkod a verembe
        ld a,10         ;41 csatornaszam
        ld b,30         ;42 ASCII 30=kurzor HOME
        exos 7          ;43 karakter ki
        ld d,y_size     ;44 sorok szama
                        ;45 D a kulso ciklus
                        ;46 azaz cycl_1
                        ;47 ciklusszamlaloja
cycl_1  ld e,x_size     ;48 oszlopok szama
                        ;49 E a belso ciklus
                        ;50 azaz cycl_2
                        ;51 ciklusszamlaloja
cycl_2  pop bc          ;52 karakterkod a verembol
        push bc         ;53 vissza a verembe
        push de         ;54 ciklusvaltozok mentese
        ld a,10         ;55 ide irunk
        exos 7          ;56 karakter ki
        pop de          ;57 ciklusvaltozok vissza
        dec e           ;58 belso szamlalo csokkentese
        jr nz,cycl_2    ;59 nem nulla -> czcl_2
        dec d           ;60 a belso ciklus veget ert
                        ;61 kulso szamlalo csokkentese
        jr nz,cycl_1    ;62 nem nulla -> cycl_1
        pop af          ;63 karakterkod A-ba
        inc a           ;64 novelese
        cp 128          ;65 (ASCII) 128?
        jr nz,cycl_0    ;66 kisebb, -> cycl_0
                        ;67
                        ;68 a videocsat. lezarasa
        ld a,10         ;69
        exos 3          ;70
        ret             ;71
                        ;72
vid     db 6            ;73
        defm "VIDEO:"   ;74
                        ;75 a szekvenciablokk
seq     db 27,"o"       ;76 kurzor kikapcs.
        db 27,"s"       ;77 scroll kikapcs.
        db 27,"C",255,32,56,32,0,0,0,0
                        ;79 palettaszinek
seqlen equ $-seq        ;80 szekv. hossz
        end             ;81