ORG 100H        ; Forditasi cim
                                ; (5-os fejleccel forditjuk;
                                ; ezert kell 100h!)
                ; EXOS valtozot iro makro definialasa
                ; (Ez a programresz itt nem forditodik le,
                ; de barhol, ahol nevevel hivatkoyunk ra,
                ; oda befoditja az ASMON)
.SET            MACRO @VALTOZO,@ERTEK
                                ; A .SET az altalunk
                                ; meghatarozott cimkenev
                LD B,1          ; iras
                LD C,@VALTOZO
                LD D,@ERTEK
                EXOS 16         ; EXOS valtozo olvasasa,
                                ; irasa vagy atbillentese
                ENDM
                                ;MACRO vege (End macro)

                LD SP,3FFFH     ; stack beallitasa

                ; EXOS valtozok beallitasa a videolap
                ; megnyitasa elott
                .SET 22,0       ; 0-as videomod (TEXT 40)
                .SET 23,0       ; 2 szinu uzemmod
                .SET 24,30      ; 30 oszlop szeles
                .SET 25,4       ; 4 sor magas

                ;csatorna megnyitasa
                LD A,1          ; A-ba a csatornaszam
                LD DE,NEV       ; DE a nev elotti hosszybyte-ra mutat
                EXOS 2          ; Csatorna megnyitasa irasra
                                ; Az EXOS 1 olvasasra nyit meg, eyz a
                                ; "VIDEO:"-nal mindegy, de pl. a
                                ; "TAPE:" vagy "DISK:" eseten nem!

                ; Videolap megjelenitese (Basic-ben:
                ; DISPLAY #1:AT 22 FROM 1 TO 4)
                LD B,1          ; Alfunkcio kodja 1 = videolap kijelzese
                LD A,1          ; A-ba a csatornaszam
                LD C,1          ; Az elso kejelzendo sor az 1-es
                LD D,4          ; 4 sort kell megjeleniteni!
                LD E,22         ; A 22. kepernyosorban kezdodik a
                                ; megjelenites
                EXOS 11         ; Specialis funkcio hivasa
                                ; (Az alfunkcio kodja a B-ben van)

                ; ESCAPE sorozatok kiirasa
                LD A,1          ; A-ba a csatornaszam
                LD BC,(HOSSZ)   ; BC-be a blokk hossza
                                ; (a hossz cimen levo ertek)
                LD DE,ESC1      ; DE-be a blokk kezdocime
                EXOS 8          ; Blokk kiirasa

                ; A szoveg kiirasa a videolapra
                LD A,1          ; A-ba a csatornaszam
                LD BC,(HOSSZ2)  ; BC-be a blokk hossza
                                ; (a HOSSZ2 cimen levo ertek)
                LD DE,SZOV      ; DE-be a blokk kezdocime
                EXOS 8          ; Blokk kiirasa

                ; Visszateres elott varakozik
                LD B,50         ; A ciklusvaltozoba 50 kerul
CIKLUS          HALT            ; Varakozo
                HALT            ;   utasitasok
                HALT
                HALT
                HALT
                DJNZ CIKLUS     ;Csokkenti a ciklusvaltozot (B) 1-el

VISSZA          LD A,1          ; A-ba a csatornaszam
                EXOS 3          ; Csatorna lezarasa
                LD DE,BASIC     ; Visszater a BASIC-be
                EXOS 26         ; Bovitesek vizsgalata

NEV             DB 6,"VIDEO:"   ; A megnyitashoz szukseges nev
HOSSZ           DW 15           ; A kiirando ESCAPE sorozat hossza
                                ; (2 byte!)
ESC1            DB 27,"o"       ; Kurzorkijelzes kikapcsolasa
                DB 27,"C",255,0,255,180,0,0,0,0
                                ; Paletta szinek beallitasa
                DB 27,"I",0     ; Tintaszin kivalasztasa (2-es
                                ; palettaszin lesz a papirszin (255)
                                ; es a 3-as lesz a tintaszin (180)
                                ; (szovegeslap!)
HOSSZ2          DW 100          ; A szoveg hossza (2 byte!)
BASIC           DB 5,"BASIC"    ; BASIC-cimke
SZOV            DB 10,"EZ A VIDEOLAP GEPI KOD"  ; A szoveg karakterei
                DB 10,13        ; Soremeles, kurzor a sor elejere
                DB 27,"I",2     ; Tintaszin valtas
                DB " SEGITSEGEVEL LETT MEGNYITVA!"
                END             ; Program vege